Edge Script documentation

• Open the Edge Chart and press the </> icon on the right edge: the Edge Script panel opens.
• Press New script. The panel opens with a working example.
• Press Save and draw (or Ctrl+Enter). The script runs on the server over the chart's candles and its lines land on the chart.
• The eye in the list turns a script on or off the chart. Several scripts can be drawn at once.

indicator("EMA crossover", overlay = true)

fast = ema(close, 12)
slow = ema(close, 26)
plot(fast, "Fast", color = orange)
plot(slow, "Slow", color = blue)

mark(crossover(fast, slow), "BUY", position = "below", color = green)
mark(crossunder(fast, slow), "SELL", position = "above", color = red)

As you type, the editor checks the code with the server's own compiler: the faulty line is underlined, and the line underneath says what is wrong, with its line and column, in your language. A misspelt name gets the nearest right one suggested.

The script runs once per bar, top to bottom, from the oldest bar to the newest. On any line, close is the close of the bar being run. The chart shows the newest 1,000 bars; the script runs over a longer history, so a long average is already warm on the first bar on screen.

Every value is a series: it has a value on every bar, and its history is read with []. close[1] is the previous bar's close, and ema(close, 20)[3] is the average three bars back.

An unknown value is na: before an average has filled, before the start of history, or from a division by zero. na turns a sum into na and is not drawn; nz(x) turns it into zero and fixnan(x) into the last known value.

The chart is read again every minute and the script runs again with the new bars. It also sees the newest, still-forming bar; a crossing on that bar can change until it closes.

Named colours: aqua, black, blue, fuchsia, gray, green, lime, maroon, navy, olive, orange, purple, red, silver, teal, white, yellow — also with the color. prefix.

A variable is made by giving a name a value with =; no type needs declaring. It is computed afresh on every bar. Assign it again with = or :=, and add to it with +=, -=, *=, /=.

A variable declared with var is set only on the first bar and carries its value from bar to bar: a counter, the price of the last signal, or a state.

var count = 0
var lastSignal = na

if crossover(close, sma(close, 50))
    count += 1
    lastSignal := close

change = (close - lastSignal) / lastSignal * 100
plot(change, "% since the last signal", pane = "Signal")

Every variable's history is read with [], up to 5,000 bars back.

Blocks are written by indentation (four spaces or a tab): there are no braces and no end.

r = rsi(close, 14)
state = 0
if r > 70
    state := 1
else if r < 30
    state := -1
else
    state := 0

// how many of the last 10 bars closed up
up = 0
for i = 0 to 9
    if close[i] > open[i]
        up += 1
plot(up, "Up bars", pane = "Count", style = "histogram")

• for i = a to b counts from a to b inclusive; by step sets the step, and it counts down when b is below a.
• while condition loops while the condition holds.
• break leaves the loop, continue goes to the next turn.
• A loop turns at most 10,000 times on one bar.
• Functions that keep a history (ema, crossover, …) cannot be called inside a loop: compute them before it.

A function is defined with name(parameters) =>: one expression on the same line, or an indented block whose last line is its value. Several values are returned as [a, b] and taken with [x, y] = f().

band(src, len, mult) =>
    mid = sma(src, len)
    dev = stdev(src, len)
    [mid + mult * dev, mid - mult * dev]

[upper, lower] = band(close, 20, 2)
plot(upper, "Upper", color = teal)
plot(lower, "Lower", color = teal)

Every call site keeps its own history: band(close, 20, 2) and band(high, 50, 3) never mix their averages. A function cannot call itself, and is defined only at the top level.

input() declares a setting of the script; its kind comes from its default: a number, true/false, a text, or a source such as close. minval and maxval bound a number. The editor shows the script's inputs and their values underneath.

length = input(20, "Length", minval = 1)
source = input(close, "Source")
show = input(true, "Show the bands")

• indicator("Name", overlay = true) names the script. overlay = true (the default) draws over the price, false in its own pane.
• plot() draws a line; style = "histogram", "area" or "circles" are the other shapes. pane = "Name" puts it in a named pane under the price; plots naming the same pane share it.
• color may change bar by bar: color = close > open ? green : red.
• hline() draws a horizontal line at a fixed price — RSI's 70/30 in a pane, say.
• mark() puts an arrow, circle or square on the bars where its condition is true, with a short text if you like.
• alert() records the bars where its condition is true; the editor lists this chart's latest.

indicator("MACD", overlay = false)
[m, signal, hist] = macd(close, 12, 26, 9)
plot(hist, "Histogram", color = hist >= 0 ? green : red, style = "histogram")
plot(m, "MACD", color = blue)
plot(signal, "Signal", color = orange)
hline(0, "Zero", color = gray)

Parameters marked ? are optional. Any parameter can be given by name: plot(x, color = red). The ta. and math. prefixes are optional: ta.ema and ema are the same. The indicators follow TradingView's own definitions.

Most Pine indicators run as they are: the //@version line, the ta. and math. prefixes, input.int and friends, typed declarations such as float x = 1, :=, plotshape and alertcondition are all accepted; Pine arguments that mean nothing here (tooltip, group, offset…) are quietly ignored.

Not there yet:

• request.security and data from another symbol or timeframe.
• Arrays, matrices, maps and switch.
• strategy.* — trade simulation.
• label, line, box and tables; plot, hline and mark are the ways to draw.
• Recursive functions.

A script runs on our servers, and every run is bounded so everybody's chart stays fast. A script that meets a limit stops with an error that says which.

Edge Script is an analysis tool; what it draws is computed from past prices and is not investment advice.